How the build is configured

The code behind the network, with room to understand it.

Stable release v32.1bitcoin/bitcoin · f0de87f04062 ↗3,020 source files · 47.5 MB stored on the server440 file guides

Release published 2026-10-28 · Snapshot fetched 2026-11-01. Latest stable release at fetch time; development branches and Git history are excluded. Only the selected code window and visible folders load here.

30,346 bytes · SHA-256 65ebefce60e7b7ef… · View upstream ↗

251endif()
252
253if(WITH_USDT)
254  find_package(USDT MODULE REQUIRED)
255endif()
256
257if(BUILD_GUI)
258  set(qt_components Core Gui Widgets LinguistTools)
259  if(ENABLE_WALLET)
260    list(APPEND qt_components Network)
261  endif()
262  if(WITH_DBUS)
263    list(APPEND qt_components DBus)
264    set(USE_DBUS TRUE)
265  endif()
266  if(BUILD_GUI_TESTS)
267    list(APPEND qt_components Test)
268  endif()
269  find_package(Qt 6.2 MODULE REQUIRED
270    COMPONENTS ${qt_components}
271  )
272  unset(qt_components)
273  if(WITH_QRENCODE)
274    find_package(QRencode MODULE REQUIRED)
275    set(USE_QRCODE TRUE)
276  endif()
277endif()
278
279include(TryAppendCXXFlags)
280include(TryAppendLinkerFlag)
281
282# Redefine/adjust per-configuration flags.
283target_compile_definitions(core_interface_debug INTERFACE
284  DEBUG
285  DEBUG_LOCKORDER
286  DEBUG_LOCKCONTENTION
287  RPC_DOC_CHECK
288  ABORT_ON_FAILED_ASSUME
289)
290
291if(WIN32)
292  #[=[
293  This build system supports two ways to build binaries for Windows.
294
295  1. Building on Windows using MSVC.
296  Implementation notes:
297  - /DWIN32 and /D_WINDOWS definitions are included into the CMAKE_CXX_FLAGS_INIT
298    and CMAKE_CXX_FLAGS_INIT variables by default.
299  - A run-time library is selected using the CMAKE_MSVC_RUNTIME_LIBRARY variable.
300  - MSVC-specific options, for example, /Zc:__cplusplus, are additionally required.
301
302  2. Cross-compiling using MinGW.
303  Implementation notes:
304  - WIN32 and _WINDOWS definitions must be provided explicitly.
305  - A run-time library must be specified explicitly using _MT definition.
306  ]=]
307
308  target_compile_definitions(core_interface INTERFACE
309    _WIN32_WINNT=0x0A00
310    _WIN32_IE=0x0A00
311    WIN32_LEAN_AND_MEAN
312    NOMINMAX
313  )
314
315  if(MSVC)
316    if(VCPKG_TARGET_TRIPLET MATCHES "-static")
317      set(msvc_library_linkage "")
318    else()
319      set(msvc_library_linkage "DLL")
320    endif()
321    set(CMAKE_MSVC_RUNTIME_LIBRARY "MultiThreaded$<$<CONFIG:Debug>:Debug>${msvc_library_linkage}")
322    unset(msvc_library_linkage)
323
324    target_compile_definitions(core_interface INTERFACE
325      _UNICODE;UNICODE
326    )
327    target_compile_options(core_interface INTERFACE
328      /utf-8
329      /Zc:preprocessor
330      /Zc:__cplusplus
331      /sdl
332    )
333    # Improve parallelism in MSBuild.
334    # See: https://devblogs.microsoft.com/cppblog/improved-parallelism-in-msbuild/.
335    list(APPEND CMAKE_VS_GLOBALS "UseMultiToolTask=true")
336  endif()
337
338  if(MINGW)
339    target_compile_definitions(core_interface INTERFACE
340      WIN32
341      _WINDOWS
342      _MT
343    )
344    # Avoid the use of aligned vector instructions when building for Windows.
345    # See https://gcc.gnu.org/bugzilla/show_bug.cgi?id=54412.
346    try_append_cxx_flags("-Wa,-muse-unaligned-vector-move" TARGET core_interface SKIP_LINK)
347    try_append_linker_flag("-static" TARGET core_interface)
348    # We support Windows 10+, however it's not possible to set these values accordingly,
349    # due to a bug in mingw-w64. See https://sourceforge.net/p/mingw-w64/bugs/968/.
350    # As a best effort, target Windows 8.
351    try_append_linker_flag("-Wl,--major-subsystem-version,6" TARGET core_interface)
352    try_append_linker_flag("-Wl,--minor-subsystem-version,2" TARGET core_interface)
353  endif()
354
355  # Workaround producing large object files, which cannot be handled by the assembler.
356  # More likely to happen with no, or lower levels of optimisation.
357  # See discussion in https://github.com/bitcoin/bitcoin/issues/28109.
358  if(CMAKE_CXX_COMPILER_ID STREQUAL "MSVC")
359    try_append_cxx_flags("/bigobj" TARGET core_interface_debug SKIP_LINK)
360  else()
361    try_append_cxx_flags("-Wa,-mbig-obj" TARGET core_interface_debug SKIP_LINK)
362  endif()
363endif()
364
365# Use 64-bit off_t on 32-bit Linux.
366if (CMAKE_SYSTEM_NAME STREQUAL "Linux" AND CMAKE_SIZEOF_VOID_P EQUAL 4)
367  # Ensure 64-bit offsets are used for filesystem accesses for 32-bit compilation.
368  target_compile_definitions(core_interface INTERFACE
369    _FILE_OFFSET_BITS=64
370  )
371endif()
372
373if(CMAKE_SYSTEM_NAME STREQUAL "Darwin")
374  target_compile_definitions(core_interface INTERFACE OBJC_OLD_DISPATCH_PROTOTYPES=0)
375  # These flags are specific to ld64, and may cause issues with other linkers.
376  # For example: GNU ld will interpret -dead_strip as -de and then try and use
377  # "ad_strip" as the symbol for the entry point.
378  try_append_linker_flag("-Wl,-dead_strip" TARGET core_interface)
379  try_append_linker_flag("-Wl,-dead_strip_dylibs" TARGET core_interface)
380  if(CMAKE_HOST_APPLE)
381    try_append_linker_flag("-Wl,-headerpad_max_install_names" TARGET core_interface)
382  endif()
383endif()
384
385# Define sanitize_interface with -fsanitize flags intended to apply to all
386# libraries and executables.
387add_library(sanitize_interface INTERFACE)
388target_link_libraries(core_interface INTERFACE sanitize_interface)
389if(SANITIZERS)
390  # Transform list of sanitizers into -fsanitize flags, replacing "fuzzer" with
391  # "fuzzer-no-link" in sanitize_interface flags, and moving "fuzzer" to
392  # fuzzer_interface flags. If -DSANITIZERS=fuzzer is specified, the fuzz test
393  # binary should be built with -fsanitize=fuzzer (so it can use libFuzzer's
394  # main function), but libraries should be built with -fsanitize=fuzzer-no-link
395  # (so they can be linked into other executables that have their own main
396  # functions).
397  string(REGEX REPLACE "(^|,)fuzzer($|,)" "\\1fuzzer-no-link\\2" sanitize_opts "${SANITIZERS}")
398  set(fuzz_flag "")
399  if(NOT sanitize_opts STREQUAL SANITIZERS)
400    set(fuzz_flag "-fsanitize=fuzzer")
401  endif()
402
403  # First check if the compiler accepts flags. If an incompatible pair like
404  # -fsanitize=address,thread is used here, this check will fail. This will also
405  # fail if a bad argument is passed, e.g. -fsanitize=undfeined
406  try_append_cxx_flags("-fsanitize=${sanitize_opts}" TARGET sanitize_interface
407    RESULT_VAR cxx_supports_sanitizers
408    SKIP_LINK
409  )
410  if(NOT cxx_supports_sanitizers)
411    message(FATAL_ERROR "Compiler did not accept requested flags.")
412  endif()
413
414  # Some compilers (e.g. GCC) require additional libraries like libasan,
415  # libtsan, libubsan, etc. Make sure linking still works with the sanitize
416  # flag. This is a separate check so we can give a better error message when
417  # the sanitize flags are supported by the compiler but the actual sanitizer
418  # libs are missing.
419  try_append_linker_flag("-fsanitize=${sanitize_opts}" VAR SANITIZER_LDFLAGS
420    SOURCE "
421      #include <cstdint>
422      #include <cstddef>
423      extern \"C\" int LLVMFuzzerTestOneInput(const uint8_t* data, size_t size) { return 0; }
424      int main() { return 0; }
425    "
426    RESULT_VAR linker_supports_sanitizers
427    NO_CACHE_IF_FAILED
428  )
429  if(NOT linker_supports_sanitizers)
430    message(FATAL_ERROR "Linker did not accept requested flags, you are missing required libraries.")
431  endif()
432endif()
433target_link_options(sanitize_interface INTERFACE ${SANITIZER_LDFLAGS})
434
435# Define fuzzer_interface with flags intended to apply to the fuzz test binary,
436# and perform a test compilation to determine correct value of
437# FUZZ_BINARY_LINKS_WITHOUT_MAIN_FUNCTION.
438if(BUILD_FUZZ_BINARY)
439  include(CheckSourceCompilesWithFlags)
440  check_cxx_source_compiles_with_flags("
441      #include <cstdint>
442      #include <cstddef>
443      extern \"C\" int LLVMFuzzerTestOneInput(const uint8_t* data, size_t size) { return 0; }
444      // No main() function.
445    " FUZZ_BINARY_LINKS_WITHOUT_MAIN_FUNCTION
446    LDFLAGS ${SANITIZER_LDFLAGS} ${fuzz_flag}
447    LINK_LIBRARIES ${FUZZ_LIBS}
448  )
449  add_library(fuzzer_interface INTERFACE)
450  target_link_options(fuzzer_interface INTERFACE ${fuzz_flag})
451  target_link_libraries(fuzzer_interface INTERFACE ${FUZZ_LIBS})
452endif()
453
454include(cmake/introspection.cmake)
455
456include(cmake/ccache.cmake)
457
458add_library(warn_interface INTERFACE)
459target_link_libraries(core_interface INTERFACE warn_interface)
460if(MSVC)
461  try_append_cxx_flags("/W3" TARGET warn_interface SKIP_LINK)
462  try_append_cxx_flags("/wd4018" TARGET warn_interface SKIP_LINK)
463  try_append_cxx_flags("/wd4146" TARGET warn_interface SKIP_LINK)
464  try_append_cxx_flags("/wd4244" TARGET warn_interface SKIP_LINK)
465  try_append_cxx_flags("/wd4267" TARGET warn_interface SKIP_LINK)
466  try_append_cxx_flags("/wd4715" TARGET warn_interface SKIP_LINK)
467  try_append_cxx_flags("/wd4805" TARGET warn_interface SKIP_LINK)
468  target_compile_definitions(warn_interface INTERFACE
469    _CRT_SECURE_NO_WARNINGS
470  )
471else()
472  try_append_cxx_flags("-Wall" TARGET warn_interface SKIP_LINK)
473  try_append_cxx_flags("-Wextra" TARGET warn_interface SKIP_LINK)
474  try_append_cxx_flags("-Wgnu" TARGET warn_interface SKIP_LINK)
475  try_append_cxx_flags("-Wcovered-switch-default" TARGET warn_interface SKIP_LINK)
476  # Some compilers will ignore -Wformat-security without -Wformat, so just combine the two here.
477  try_append_cxx_flags("-Wformat -Wformat-security" TARGET warn_interface SKIP_LINK)
478  try_append_cxx_flags("-Wvla" TARGET warn_interface SKIP_LINK)
479  try_append_cxx_flags("-Wshadow-field" TARGET warn_interface SKIP_LINK)
480  try_append_cxx_flags("-Wthread-safety" TARGET warn_interface SKIP_LINK)
481  try_append_cxx_flags("-Wthread-safety-pointer" TARGET warn_interface SKIP_LINK)
482  try_append_cxx_flags("-Wloop-analysis" TARGET warn_interface SKIP_LINK)
483  try_append_cxx_flags("-Wredundant-decls" TARGET warn_interface SKIP_LINK)
484  try_append_cxx_flags("-Wunused-member-function" TARGET warn_interface SKIP_LINK)
485  try_append_cxx_flags("-Wdate-time" TARGET warn_interface SKIP_LINK)
486  try_append_cxx_flags("-Wconditional-uninitialized" TARGET warn_interface SKIP_LINK)
487  try_append_cxx_flags("-Wduplicated-branches" TARGET warn_interface SKIP_LINK)
488  try_append_cxx_flags("-Wduplicated-cond" TARGET warn_interface SKIP_LINK)
489  try_append_cxx_flags("-Wlogical-op" TARGET warn_interface SKIP_LINK)
490  try_append_cxx_flags("-Woverloaded-virtual" TARGET warn_interface SKIP_LINK)
491  try_append_cxx_flags("-Wsuggest-override" TARGET warn_interface SKIP_LINK)
492  try_append_cxx_flags("-Wimplicit-fallthrough" TARGET warn_interface SKIP_LINK)
493  try_append_cxx_flags("-Wunreachable-code" TARGET warn_interface SKIP_LINK)
494  try_append_cxx_flags("-Wdocumentation" TARGET warn_interface SKIP_LINK)
495  try_append_cxx_flags("-Wself-assign" TARGET warn_interface SKIP_LINK)
496  try_append_cxx_flags("-Wbidi-chars=any" TARGET warn_interface SKIP_LINK)
497  try_append_cxx_flags("-Wundef" TARGET warn_interface SKIP_LINK)
498  try_append_cxx_flags("-Wleading-whitespace=spaces" TARGET warn_interface SKIP_LINK)
499  try_append_cxx_flags("-Wtrailing-whitespace=any" TARGET warn_interface SKIP_LINK)
500

FILE GUIDE · KEY SECTIONS

How the build is configured

The root CMake file configures project metadata, toolchain requirements, optional components and subdirectories. This page explains its organization rather than every build branch.

Line 10 ↗

Build prerequisites

The first checks require a supported CMake version and reject an in-source build. Keeping generated files outside the source tree avoids mixing build artifacts with source.

Line 30 ↗

Release identity

The version components and release flag define this snapshot's build identity. They feed the generated bitcoin-build-config.h header.

Line 84 ↗

Language requirements

The build requests C++20 and disables compiler-specific language extensions for the standard selection.

Line 117 ↗

Optional components

Build switches decide whether components such as the wallet are compiled. Other sections discover dependencies and configure targets. Changing a build switch does not automatically change network consensus.

Independent explanations by MyBitcoinExplorer. Not affiliated with or endorsed by Bitcoin Core. Guides are educational and do not replace the source or its tests.

Bitcoin Core source © its contributors, distributed under the MIT license. Original notices and bundled third-party licenses are retained in the source tree.