How the build is configured

501  # Some compilers (gcc) ignore unknown -Wno-* options, but warn about all
502  # unknown options if any other warning is produced. Test the -Wfoo case, and
503  # set the -Wno-foo case if it works.
504  try_append_cxx_flags("-Wunused-parameter" TARGET warn_interface SKIP_LINK
505    IF_CHECK_PASSED "-Wno-unused-parameter"
506  )
507endif()
508
509configure_file(cmake/script/Coverage.cmake Coverage.cmake USE_SOURCE_PERMISSIONS COPYONLY)
510configure_file(cmake/script/CoverageInclude.cmake.in CoverageInclude.cmake USE_SOURCE_PERMISSIONS @ONLY)
511configure_file(cmake/script/cov_tool_wrapper.sh.in cov_tool_wrapper.sh.in USE_SOURCE_PERMISSIONS COPYONLY)
512configure_file(contrib/filter-lcov.py filter-lcov.py USE_SOURCE_PERMISSIONS COPYONLY)
513
514# Don't allow extended (non-ASCII) symbols in identifiers. This is easier for code review.
515try_append_cxx_flags("-fno-extended-identifiers" TARGET core_interface SKIP_LINK)
516
517# Set `-fmacro-prefix-map`, so that source file names are expanded without the
518# src prefix.
519try_append_cxx_flags("-fmacro-prefix-map=A=B" TARGET core_interface SKIP_LINK
520  IF_CHECK_PASSED "-fmacro-prefix-map=${PROJECT_SOURCE_DIR}/src=."
521)
522
523# GCC versions 13.2 (and earlier) are subject to a class of bugs, see
524# https://gcc.gnu.org/bugzilla/show_bug.cgi?id=90348 and the meta bug
525# https://gcc.gnu.org/bugzilla/show_bug.cgi?id=111843. To work around that, set
526# -fstack-reuse=none for all gcc builds. (Only gcc understands this flag).
527try_append_cxx_flags("-fstack-reuse=none" TARGET core_interface)
528
529if(MSVC)
530  try_append_linker_flag("/DYNAMICBASE" TARGET core_interface)
531  try_append_linker_flag("/HIGHENTROPYVA" TARGET core_interface)
532  try_append_linker_flag("/NXCOMPAT" TARGET core_interface)
533else()
534
535  # _FORTIFY_SOURCE requires that there is some level of optimization,
536  # otherwise it does nothing and just creates a compiler warning.
537  try_append_cxx_flags("-U_FORTIFY_SOURCE -D_FORTIFY_SOURCE=3"
538    RESULT_VAR cxx_supports_fortify_source
539    SOURCE "int main() {
540            # if !defined __OPTIMIZE__ || __OPTIMIZE__ <= 0
541              #error
542            #endif
543            }"
544  )
545  if(cxx_supports_fortify_source)
546    target_compile_options(core_interface INTERFACE
547      -U_FORTIFY_SOURCE
548      -D_FORTIFY_SOURCE=3
549    )
550  endif()
551  unset(cxx_supports_fortify_source)
552
553  try_append_cxx_flags("-Wstack-protector" TARGET core_interface SKIP_LINK)
554  try_append_cxx_flags("-fstack-protector-all" TARGET core_interface)
555  try_append_cxx_flags("-fcf-protection=full" TARGET core_interface)
556
557  if(MINGW)
558    # stack-clash-protection is a no-op for Windows.
559    # See https://gcc.gnu.org/bugzilla/show_bug.cgi?id=90458 for more details.
560  else()
561    try_append_cxx_flags("-fstack-clash-protection" TARGET core_interface)
562  endif()
563
564  if(CMAKE_SYSTEM_PROCESSOR STREQUAL "aarch64" OR CMAKE_SYSTEM_PROCESSOR STREQUAL "arm64")
565    if(CMAKE_SYSTEM_NAME STREQUAL "Darwin")
566      try_append_cxx_flags("-mbranch-protection=bti" TARGET core_interface SKIP_LINK)
567    else()
568      try_append_cxx_flags("-mbranch-protection=standard" TARGET core_interface SKIP_LINK)
569    endif()
570  endif()
571
572  try_append_linker_flag("-Wl,--enable-reloc-section" TARGET core_interface)
573  try_append_linker_flag("-Wl,--dynamicbase" TARGET core_interface)
574  try_append_linker_flag("-Wl,--nxcompat" TARGET core_interface)
575  try_append_linker_flag("-Wl,--high-entropy-va" TARGET core_interface)
576  try_append_linker_flag("-Wl,-z,relro" TARGET core_interface)
577  try_append_linker_flag("-Wl,-z,now" TARGET core_interface)
578  # TODO: This can be dropped once Bitcoin Core no longer supports
579  #       NetBSD 10.0 or if upstream fix is backported.
580  # NetBSD's dynamic linker ld.elf_so < 11.0 supports exactly 2
581  # `PT_LOAD` segments and binaries linked with `-z separate-code`
582  # have 4 `PT_LOAD` segments.
583  # Relevant discussions:
584  # - https://github.com/bitcoin/bitcoin/pull/28724#issuecomment-2589347934
585  # - https://mail-index.netbsd.org/tech-userlevel/2023/01/05/msg013666.html
586  if(CMAKE_SYSTEM_NAME STREQUAL "NetBSD" AND CMAKE_SYSTEM_VERSION VERSION_LESS 11.0)
587    try_append_linker_flag("-Wl,-z,noseparate-code" TARGET core_interface)
588  else()
589    try_append_linker_flag("-Wl,-z,separate-code" TARGET core_interface)
590  endif()
591  if(CMAKE_SYSTEM_NAME STREQUAL "Darwin")
592    try_append_linker_flag("-Wl,-fixup_chains" TARGET core_interface)
593  endif()
594endif()
595
596if(REDUCE_EXPORTS)
597  set(CMAKE_CXX_VISIBILITY_PRESET hidden)
598  set(CMAKE_VISIBILITY_INLINES_HIDDEN ON)
599  try_append_linker_flag("-Wl,--exclude-libs,ALL" TARGET core_interface)
600  try_append_linker_flag("-Wl,-no_exported_symbols" VAR CMAKE_EXE_LINKER_FLAGS)
601endif()
602
603# Prefer Unix-style package components over frameworks on macOS.
604# This improves compatibility with Python version managers.
605set(Python3_FIND_FRAMEWORK LAST CACHE STRING "")
606# Search for generic names before more specialized ones. This
607# improves compatibility with Python version managers that use shims.
608set(Python3_FIND_UNVERSIONED_NAMES FIRST CACHE STRING "")
609mark_as_advanced(Python3_FIND_FRAMEWORK Python3_FIND_UNVERSIONED_NAMES)
610find_package(Python3 3.10 COMPONENTS Interpreter)
611if(NOT TARGET Python3::Interpreter)
612  list(APPEND configure_warnings
613    "Minimum required Python not found."
614  )
615endif()
616
617target_compile_definitions(core_interface INTERFACE ${DEPENDS_COMPILE_DEFINITIONS})
618target_compile_definitions(core_interface_relwithdebinfo INTERFACE ${DEPENDS_COMPILE_DEFINITIONS_RELWITHDEBINFO})
619target_compile_definitions(core_interface_debug INTERFACE ${DEPENDS_COMPILE_DEFINITIONS_DEBUG})
620
621# If the {CXX,LD}FLAGS environment variables are defined during building depends
622# and configuring this build system, their content might be duplicated.
623if(DEFINED ENV{CXXFLAGS})
624  deduplicate_flags(CMAKE_CXX_FLAGS)
625endif()
626if(DEFINED ENV{LDFLAGS})
627  deduplicate_flags(CMAKE_EXE_LINKER_FLAGS)
628endif()
629
630if(BUILD_TESTS)
631  enable_testing()
632endif()
633
634if(CMAKE_VERSION VERSION_GREATER_EQUAL 3.29)
635  # have "make test" depend on "make all"
636  set(CMAKE_SKIP_TEST_ALL_DEPENDENCY FALSE)
637endif()
638
639add_subdirectory(test)
640add_subdirectory(doc)
641
642add_subdirectory(src)
643
644include(Maintenance)
645setup_split_debug_script()
646add_windows_deploy_target()
647add_macos_deploy_target()
648
649message("\n")
650message("Configure summary")
651message("=================")
652message("Executables:")
653message("  bitcoin ............................. ${BUILD_BITCOIN_BIN}")
654message("  bitcoind ............................ ${BUILD_DAEMON}")
655if(BUILD_DAEMON AND ENABLE_IPC)
656  set(bitcoin_daemon_status ON)
657else()
658  set(bitcoin_daemon_status OFF)
659endif()
660message("  bitcoin-node (multiprocess) ......... ${bitcoin_daemon_status}")
661message("  bitcoin-qt (GUI) .................... ${BUILD_GUI}")
662if(BUILD_GUI AND ENABLE_IPC)
663  set(bitcoin_gui_status ON)
664else()
665  set(bitcoin_gui_status OFF)
666endif()
667message("  bitcoin-gui (GUI, multiprocess) ..... ${bitcoin_gui_status}")
668message("  bitcoin-cli ......................... ${BUILD_CLI}")
669message("  bitcoin-tx .......................... ${BUILD_TX}")
670message("  bitcoin-util ........................ ${BUILD_UTIL}")
671message("  bitcoin-wallet ...................... ${BUILD_WALLET_TOOL}")
672message("  bitcoin-chainstate (experimental) ... ${BUILD_UTIL_CHAINSTATE}")
673message("  libbitcoinkernel (experimental) ..... ${BUILD_KERNEL_LIB}")
674message("  kernel-test (experimental) .......... ${BUILD_KERNEL_TEST}")
675message("Optional features:")
676message("  wallet support ...................... ${ENABLE_WALLET}")
677message("  external signer ..................... ${ENABLE_EXTERNAL_SIGNER}")
678message("  ZeroMQ .............................. ${WITH_ZMQ}")
679if(ENABLE_IPC)
680  if (WITH_EXTERNAL_LIBMULTIPROCESS)
681    set(ipc_status "ON (with external libmultiprocess)")
682  else()
683    set(ipc_status ON)
684  endif()
685else()
686  set(ipc_status OFF)
687endif()
688message("  IPC ................................. ${ipc_status}")
689message("  Embedded ASMap ...................... ${WITH_EMBEDDED_ASMAP}")
690message("  USDT tracing ........................ ${WITH_USDT}")
691message("  QR code (GUI) ....................... ${WITH_QRENCODE}")
692message("  DBus (GUI) .......................... ${WITH_DBUS}")
693message("Tests:")
694message("  test_bitcoin ........................ ${BUILD_TESTS}")
695message("  test_bitcoin-qt ..................... ${BUILD_GUI_TESTS}")
696message("  bench_bitcoin ....................... ${BUILD_BENCH}")
697message("  fuzz binary ......................... ${BUILD_FUZZ_BINARY}")
698message("")
699if(CMAKE_CROSSCOMPILING)
700  set(cross_status "TRUE, for ${CMAKE_SYSTEM_NAME}, ${CMAKE_SYSTEM_PROCESSOR}")
701else()
702  set(cross_status "FALSE")
703endif()
704message("Cross compiling ....................... ${cross_status}")
705message("C++ compiler .......................... ${CMAKE_CXX_COMPILER_ID} ${CMAKE_CXX_COMPILER_VERSION}, ${CMAKE_CXX_COMPILER}")
706include(FlagsSummary)
707flags_summary()
708message("Treat compiler warnings as errors ..... ${CMAKE_COMPILE_WARNING_AS_ERROR}")
709message("Use ccache for compiling .............. ${WITH_CCACHE}")
710message("\n")
711if(configure_warnings)
712    message("  ******\n")
713    foreach(warning IN LISTS configure_warnings)
714      message(WARNING "${warning}")
715    endforeach()
716    message("  ******\n")
717    message(AUTHOR_WARNING "Warnings have been encountered!")
718endif()
719
720# We want all build properties to be encapsulated properly.
721include(WarnAboutGlobalProperties)
722