1# Copyright (c) 2023-present The Bitcoin Core developers
2# Distributed under the MIT software license, see the accompanying
3# file COPYING or https://opensource.org/license/mit/.
4
5include(CheckCXXSourceCompiles)
6include(CheckCXXSymbolExists)
7
8check_cxx_symbol_exists(O_CLOEXEC "fcntl.h" HAVE_O_CLOEXEC)
9check_cxx_symbol_exists(fdatasync "unistd.h" HAVE_FDATASYNC)
10check_cxx_symbol_exists(fork "unistd.h" HAVE_DECL_FORK)
11if (NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
12  check_cxx_symbol_exists(pipe2 "unistd.h" HAVE_DECL_PIPE2)
13endif()
14check_cxx_symbol_exists(setsid "unistd.h" HAVE_DECL_SETSID)
15
16if(NOT WIN32)
17  include(TestAppendRequiredLibraries)
18  test_append_socket_library(core_interface)
19endif()
20
21include(TestAppendRequiredLibraries)
22if(NOT CMAKE_SYSTEM_NAME STREQUAL "Generic")
23test_append_atomic_library(core_interface)
24endif()
25
26# Even though ::system is part of the standard library, we still check
27# for it, to support building targets that don't have it, such as iOS.
28check_cxx_symbol_exists(std::system "cstdlib" HAVE_STD_SYSTEM)
29if(HAVE_STD_SYSTEM)
30  set(HAVE_SYSTEM 1)
31endif()
32
33check_cxx_source_compiles("
34  #include <string.h>
35
36  int main()
37  {
38    char buf[100];
39    char* p{strerror_r(0, buf, sizeof buf)};
40    (void)p;
41  }
42  " STRERROR_R_CHAR_P
43)
44
45# Check for malloc_info (for memory statistics information in getmemoryinfo).
46check_cxx_symbol_exists(malloc_info "malloc.h" HAVE_MALLOC_INFO)
47
48# Check for mallopt(M_ARENA_MAX) (to set glibc arenas).
49check_cxx_source_compiles("
50  #include <malloc.h>
51
52  int main()
53  {
54    mallopt(M_ARENA_MAX, 1);
55  }
56  " HAVE_MALLOPT_ARENA_MAX
57)
58
59# Check for posix_fallocate().
60check_cxx_source_compiles("
61  #include <fcntl.h>
62
63  int main()
64  {
65    return posix_fallocate(0, 0, 0);
66  }
67  " HAVE_POSIX_FALLOCATE
68)
69
70# Check for strong getauxval() support in the system headers.
71check_cxx_source_compiles("
72  #include <sys/auxv.h>
73
74  int main()
75  {
76    getauxval(AT_HWCAP);
77  }
78  " HAVE_STRONG_GETAUXVAL
79)
80
81# Check for SetThreadDescription(), which is missing from mingw-w64 headers
82# before 12.0.0.
83check_cxx_symbol_exists(SetThreadDescription "windows.h" HAVE_SETTHREADDESCRIPTION)
84
85# Check for UNIX sockets.
86check_cxx_source_compiles("
87  #include <sys/socket.h>
88  #include <sys/un.h>
89
90  int main()
91  {
92    struct sockaddr_un addr;
93    addr.sun_family = AF_UNIX;
94  }
95  " HAVE_SOCKADDR_UN
96)
97
98# Check for different ways of gathering OS randomness:
99# - Linux getrandom()
100check_cxx_source_compiles("
101  #include <sys/random.h>
102
103  int main()
104  {
105    getrandom(nullptr, 32, 0);
106  }
107  " HAVE_GETRANDOM
108)
109
110# - BSD getentropy()
111check_cxx_source_compiles("
112  #include <sys/random.h>
113
114  int main()
115  {
116    getentropy(nullptr, 32);
117  }
118  " HAVE_GETENTROPY_RAND
119)
120
121
122# - BSD sysctl()
123check_cxx_source_compiles("
124  #include <sys/types.h>
125  #include <sys/sysctl.h>
126
127  #ifdef __linux__
128  #error Don't use sysctl on Linux, it's deprecated even when it works
129  #endif
130
131  int main()
132  {
133    sysctl(nullptr, 2, nullptr, nullptr, nullptr, 0);
134  }
135  " HAVE_SYSCTL
136)
137
138# - BSD sysctl(KERN_ARND)
139check_cxx_source_compiles("
140  #include <sys/types.h>
141  #include <sys/sysctl.h>
142
143  #ifdef __linux__
144  #error Don't use sysctl on Linux, it's deprecated even when it works
145  #endif
146
147  int main()
148  {
149    static int name[2] = {CTL_KERN, KERN_ARND};
150    sysctl(name, 2, nullptr, nullptr, nullptr, 0);
151  }
152  " HAVE_SYSCTL_ARND
153)
154
155if(NOT MSVC)
156  include(CheckSourceCompilesWithFlags)
157
158  # Check for SSE4.1 intrinsics.
159  set(SSE41_CXXFLAGS -msse4.1)
160  check_cxx_source_compiles_with_flags("
161    #include <immintrin.h>
162
163    int main()
164    {
165      __m128i a = _mm_set1_epi32(0);
166      __m128i b = _mm_set1_epi32(1);
167      __m128i r = _mm_blend_epi16(a, b, 0xFF);
168      return _mm_extract_epi32(r, 3);
169    }
170    " HAVE_SSE41
171    CXXFLAGS ${SSE41_CXXFLAGS}
172  )
173
174  # Check for AVX2 intrinsics.
175  set(AVX2_CXXFLAGS -mavx -mavx2)
176  check_cxx_source_compiles_with_flags("
177    #include <immintrin.h>
178
179    int main()
180    {
181      __m256i l = _mm256_set1_epi32(0);
182      return _mm256_extract_epi32(l, 7);
183    }
184    " HAVE_AVX2
185    CXXFLAGS ${AVX2_CXXFLAGS}
186  )
187
188  # Check for x86 SHA-NI intrinsics.
189  set(X86_SHANI_CXXFLAGS -msse4 -msha)
190  check_cxx_source_compiles_with_flags("
191    #include <immintrin.h>
192
193    int main()
194    {
195      __m128i i = _mm_set1_epi32(0);
196      __m128i j = _mm_set1_epi32(1);
197      __m128i k = _mm_set1_epi32(2);
198      return _mm_extract_epi32(_mm_sha256rnds2_epu32(i, j, k), 0);
199    }
200    " HAVE_X86_SHANI
201    CXXFLAGS ${X86_SHANI_CXXFLAGS}
202  )
203
204  # Check for ARMv8 SHA-NI intrinsics.
205  set(ARM_SHANI_CXXFLAGS -march=armv8-a+crypto)
206  check_cxx_source_compiles_with_flags("
207    #include <arm_neon.h>
208
209    int main()
210    {
211      uint32x4_t a, b, c;
212      vsha256h2q_u32(a, b, c);
213      vsha256hq_u32(a, b, c);
214      vsha256su0q_u32(a, b);
215      vsha256su1q_u32(a, b, c);
216    }
217    " HAVE_ARM_SHANI
218    CXXFLAGS ${ARM_SHANI_CXXFLAGS}
219  )
220endif()
221