Inside Bitcoin

1# Copyright (c) 2025-present The Bitcoin Core developers
2# Distributed under the MIT software license, see the accompanying
3# file COPYING or http://www.opensource.org/licenses/mit-license.php.
4
5cmake_minimum_required(VERSION 3.22)
6
7set(input_variables
8  PROJECT_SOURCE_DIR
9  COPYRIGHT_HOLDERS
10  LUPDATE_EXECUTABLE
11  XGETTEXT_EXECUTABLE
12)
13
14foreach(var IN LISTS input_variables)
15  if(NOT DEFINED ${var})
16    message(FATAL_ERROR "Variable '${var}' is not defined!")
17  endif()
18endforeach()
19
20# Extract _("...") strings for translation and convert to Qt stringdefs so that
21# they can be picked up by Qt linguist.
22function(extract_strings output)
23  execute_process(
24    COMMAND ${XGETTEXT_EXECUTABLE}
25      --output=bitcoinstrings.po
26      --no-location
27      --from-code=utf-8
28      --keyword=_
29      ${ARGN}
30    COMMAND_ERROR_IS_FATAL ANY
31  )
32
33  file(STRINGS "bitcoinstrings.po" text ENCODING "UTF-8")
34
35  set(messages "${COPYRIGHT_HOLDERS}")
36  foreach(line IN LISTS text)
37    if(line MATCHES "^msgid \"(.*)\"$")
38      set(msgid "${CMAKE_MATCH_1}")
39    elseif(line MATCHES "^\"(.*)\"$")
40      string(APPEND msgid "${CMAKE_MATCH_1}")
41    elseif(line MATCHES "^msgstr .*$" AND NOT msgid STREQUAL "")
42      # CMake uses ';' as a list separator.
43      # We need to temporarily replace that in order to keep strings intact.
44      string(REPLACE ";" "<cmake-semicolon>" msgid "${msgid}")
45      list(APPEND messages "${msgid}")
46    endif()
47  endforeach()
48
49  set(content [[// Automatically generated by translate.cmake
50
51#include <QtGlobal>
52
53#ifdef __GNUC__
54#define UNUSED __attribute__((unused))
55#else
56#define UNUSED
57#endif
58
59static const char UNUSED *bitcoin_strings[] = {
60]])
61
62  set(prefix "QT_TRANSLATE_NOOP(\"bitcoin-core\", \"")
63  set(suffix "\"),\n")
64
65  list(SORT messages)
66  list(JOIN messages "${suffix}${prefix}" messages_str)
67  string(APPEND content "${prefix}${messages_str}${suffix}")
68  string(APPEND content "};\n")
69  string(REPLACE "<cmake-semicolon>" ";" content "${content}")
70
71  file(WRITE "${output}" "${content}")
72endfunction()
73
74file(GLOB_RECURSE translatable_sources
75  "${PROJECT_SOURCE_DIR}/src/*.h"
76  "${PROJECT_SOURCE_DIR}/src/*.cpp"
77  "${PROJECT_SOURCE_DIR}/src/*.mm"
78)
79
80file(GLOB_RECURSE qt_translatable_sources
81  "${PROJECT_SOURCE_DIR}/src/qt/*.h"
82  "${PROJECT_SOURCE_DIR}/src/qt/*.cpp"
83  "${PROJECT_SOURCE_DIR}/src/qt/*.mm"
84)
85
86file(GLOB ui_files
87  "${PROJECT_SOURCE_DIR}/src/qt/forms/*.ui"
88)
89
90set(subtrees crc32c crypto/ctaes leveldb minisketch secp256k1)
91set(exclude_dirs bench compat crypto support test univalue)
92foreach(directory IN LISTS subtrees exclude_dirs)
93  list(FILTER translatable_sources
94    EXCLUDE REGEX "${PROJECT_SOURCE_DIR}/src/${directory}/.*"
95  )
96endforeach()
97
98extract_strings("${PROJECT_SOURCE_DIR}/src/qt/bitcoinstrings.cpp"
99  ${translatable_sources}
100)
101
102execute_process(
103  COMMAND ${LUPDATE_EXECUTABLE}
104    -no-obsolete
105    -sort-messages
106    -I ${PROJECT_SOURCE_DIR}/src
107    -locations none
108    -target-language en
109    ${ui_files}
110    ${qt_translatable_sources}
111    ${PROJECT_SOURCE_DIR}/src/qt/bitcoinstrings.cpp
112    -ts ${PROJECT_SOURCE_DIR}/src/qt/locale/bitcoin_en.ts
113  COMMAND_ERROR_IS_FATAL ANY
114)
115