Inside Bitcoin

1# Copyright (c) 2023-present The Bitcoin Core developers
2# Distributed under the MIT software license, see the accompanying
3# file COPYING or https://opensource.org/license/mit/.
4
5function(create_test_config)
6  set(abs_top_srcdir ${PROJECT_SOURCE_DIR})
7  set(abs_top_builddir ${PROJECT_BINARY_DIR})
8  set(EXEEXT ${CMAKE_EXECUTABLE_SUFFIX})
9
10  macro(set_configure_variable var conf_var)
11    if(${var})
12      set(${conf_var}_VALUE true)
13    else()
14      set(${conf_var}_VALUE false)
15    endif()
16  endmacro()
17
18  set_configure_variable(ENABLE_WALLET ENABLE_WALLET)
19  set_configure_variable(BUILD_BENCH BUILD_BENCH)
20  set_configure_variable(BUILD_CLI BUILD_BITCOIN_CLI)
21  set_configure_variable(BUILD_TX BUILD_BITCOIN_TX)
22  set_configure_variable(BUILD_UTIL BUILD_BITCOIN_UTIL)
23  set_configure_variable(BUILD_UTIL_CHAINSTATE BUILD_BITCOIN_CHAINSTATE)
24  set_configure_variable(BUILD_WALLET_TOOL BUILD_BITCOIN_WALLET)
25  set_configure_variable(BUILD_DAEMON BUILD_BITCOIND)
26  set_configure_variable(BUILD_FUZZ_BINARY ENABLE_FUZZ_BINARY)
27  set_configure_variable(WITH_ZMQ ENABLE_ZMQ)
28  set_configure_variable(WITH_EMBEDDED_ASMAP ENABLE_EMBEDDED_ASMAP)
29  set_configure_variable(ENABLE_EXTERNAL_SIGNER ENABLE_EXTERNAL_SIGNER)
30  set_configure_variable(WITH_USDT ENABLE_USDT_TRACEPOINTS)
31  set_configure_variable(ENABLE_IPC ENABLE_IPC)
32  set_configure_variable(BUILD_GUI BUILD_GUI)
33
34  configure_file(config.ini.in config.ini USE_SOURCE_PERMISSIONS @ONLY)
35endfunction()
36
37create_test_config()
38
39
40function(create_test_directory_links)
41  file(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/functional)
42  file(GLOB functional
43    LIST_DIRECTORIES FALSE
44    RELATIVE ${CMAKE_CURRENT_SOURCE_DIR}
45    functional/*.html
46    functional/*.py
47  )
48
49  file(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/functional/data)
50  file(GLOB functional_data
51    LIST_DIRECTORIES FALSE
52    RELATIVE ${CMAKE_CURRENT_SOURCE_DIR}
53    functional/data/*.json
54    functional/data/*.py
55  )
56
57  file(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/functional/mocks)
58  file(GLOB functional_mocks
59    LIST_DIRECTORIES FALSE
60    RELATIVE ${CMAKE_CURRENT_SOURCE_DIR}
61    functional/mocks/*.py
62  )
63
64  file(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/functional/test_framework)
65  file(GLOB functional_test_framework
66    LIST_DIRECTORIES FALSE
67    RELATIVE ${CMAKE_CURRENT_SOURCE_DIR}
68    functional/test_framework/*.csv
69    functional/test_framework/*.py
70  )
71
72  file(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/functional/test_framework/crypto)
73  file(GLOB functional_test_framework_crypto
74    LIST_DIRECTORIES FALSE
75    RELATIVE ${CMAKE_CURRENT_SOURCE_DIR}
76    functional/test_framework/crypto/*.csv
77    functional/test_framework/crypto/*.py
78  )
79
80  file(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/fuzz)
81  set(files_to_link
82    ${functional}
83    ${functional_data}
84    ${functional_mocks}
85    ${functional_test_framework}
86    ${functional_test_framework_crypto}
87    fuzz/test_runner.py
88  )
89
90  foreach(f IN LISTS files_to_link)
91    if(CMAKE_HOST_WIN32)
92      set(symlink)
93    else()
94      set(symlink SYMBOLIC)
95    endif()
96    file(CREATE_LINK ${CMAKE_CURRENT_SOURCE_DIR}/${f} ${CMAKE_CURRENT_BINARY_DIR}/${f} COPY_ON_ERROR ${symlink})
97  endforeach()
98
99  configure_file(${PROJECT_SOURCE_DIR}/src/test/data/siphash.json ${PROJECT_BINARY_DIR}/src/test/data/siphash.json COPYONLY)
100endfunction()
101
102create_test_directory_links()
103