Inside Bitcoin

1# Copyright (c) 2023-present The Bitcoin Core developers
2# Distributed under the MIT software license, see the accompanying
3# file COPYING or https://opensource.org/license/mit/.
4
5# Do not use generator expressions in test sources because the
6# SOURCES property is processed to gather test suite macros.
7add_executable(test_bitcoin
8  main.cpp
9  addrman_tests.cpp
10  allocator_tests.cpp
11  amount_tests.cpp
12  argsman_tests.cpp
13  arith_uint256_tests.cpp
14  banman_tests.cpp
15  base32_tests.cpp
16  base58_tests.cpp
17  base64_tests.cpp
18  baseindex_tests.cpp
19  bech32_tests.cpp
20  bip32_tests.cpp
21  bip324_tests.cpp
22  blockchain_tests.cpp
23  blockencodings_tests.cpp
24  blockfilter_index_tests.cpp
25  blockfilter_tests.cpp
26  blockmanager_tests.cpp
27  blockpolicyestimator_tests.cpp
28  bloom_tests.cpp
29  bswap_tests.cpp
30  btcsignals_tests.cpp
31  caches_tests.cpp
32  chain_tests.cpp
33  chainstate_write_tests.cpp
34  checkqueue_tests.cpp
35  cluster_linearize_tests.cpp
36  coins_tests.cpp
37  coinscachepair_tests.cpp
38  coinstatsindex_tests.cpp
39  coinsviewoverlay_tests.cpp
40  common_url_tests.cpp
41  compress_tests.cpp
42  crypto_tests.cpp
43  cuckoocache_tests.cpp
44  dbwrapper_tests.cpp
45  denialofservice_tests.cpp
46  descriptor_tests.cpp
47  disconnected_transactions.cpp
48  fees_util_tests.cpp
49  feefrac_tests.cpp
50  feerounder_tests.cpp
51  flatfile_tests.cpp
52  fs_tests.cpp
53  getarg_tests.cpp
54  hash_tests.cpp
55  headers_sync_chainwork_tests.cpp
56  httpserver_tests.cpp
57  i2p_tests.cpp
58  interfaces_tests.cpp
59  key_io_tests.cpp
60  key_tests.cpp
61  logging_tests.cpp
62  mempool_tests.cpp
63  mempool_fee_estimator_tests.cpp
64  merkle_tests.cpp
65  merkleblock_tests.cpp
66  miner_tests.cpp
67  miniminer_tests.cpp
68  miniscript_tests.cpp
69  minisketch_tests.cpp
70  multisig_tests.cpp
71  bip328_tests.cpp
72  net_peer_connection_tests.cpp
73  net_peer_eviction_tests.cpp
74  net_tests.cpp
75  netbase_tests.cpp
76  node_init_tests.cpp
77  node_warnings_tests.cpp
78  orphanage_tests.cpp
79  pcp_tests.cpp
80  peerman_tests.cpp
81  pmt_tests.cpp
82  pool_tests.cpp
83  pow_tests.cpp
84  prevector_tests.cpp
85  private_broadcast_tests.cpp
86  psbt_tests.cpp
87  random_tests.cpp
88  rbf_tests.cpp
89  rest_tests.cpp
90  result_tests.cpp
91  reverselock_tests.cpp
92  rpc_tests.cpp
93  sanity_tests.cpp
94  scheduler_tests.cpp
95  script_assets_tests.cpp
96  script_p2sh_tests.cpp
97  script_parse_tests.cpp
98  script_segwit_tests.cpp
99  script_standard_tests.cpp
100  script_tests.cpp
101  scriptnum_tests.cpp
102  serfloat_tests.cpp
103  serialize_tests.cpp
104  settings_tests.cpp
105  sighash_tests.cpp
106  sigopcount_tests.cpp
107  skiplist_tests.cpp
108  sock_tests.cpp
109  span_tests.cpp
110  streams_tests.cpp
111  sync_tests.cpp
112  system_ram_tests.cpp
113  system_tests.cpp
114  testnet4_miner_tests.cpp
115  threadpool_tests.cpp
116  timeoffsets_tests.cpp
117  torcontrol_tests.cpp
118  transaction_tests.cpp
119  translation_tests.cpp
120  txdownload_tests.cpp
121  txgraph_tests.cpp
122  txindex_tests.cpp
123  txospenderindex_tests.cpp
124  txpackage_tests.cpp
125  txreconciliation_tests.cpp
126  txrequest_tests.cpp
127  txvalidation_tests.cpp
128  txvalidationcache_tests.cpp
129  uint256_tests.cpp
130  util_check_tests.cpp
131  util_expected_tests.cpp
132  util_string_tests.cpp
133  util_tests.cpp
134  util_threadnames_tests.cpp
135  util_trace_tests.cpp
136  validation_block_tests.cpp
137  validation_chainstate_tests.cpp
138  validation_chainstatemanager_tests.cpp
139  validation_flush_tests.cpp
140  validation_tests.cpp
141  validationinterface_tests.cpp
142  versionbits_tests.cpp
143)
144
145include(TargetDataSources)
146target_json_data_sources(test_bitcoin
147  data/base58_encode_decode.json
148  data/bip341_wallet_vectors.json
149  data/blockfilters.json
150  data/key_io_invalid.json
151  data/key_io_valid.json
152  data/script_tests.json
153  data/sighash.json
154  data/siphash.json
155  data/tx_invalid.json
156  data/tx_valid.json
157)
158target_raw_data_sources(test_bitcoin NAMESPACE test::data
159  data/asmap.raw
160)
161
162add_windows_application_manifest(test_bitcoin)
163
164target_link_libraries(test_bitcoin
165  core_interface
166  test_util
167  bitcoin_cli
168  bitcoin_node
169  bitcoin_consensus
170  minisketch
171  secp256k1
172  Boost::headers
173  $<TARGET_NAME_IF_EXISTS:USDT::headers>
174)
175
176function(add_boost_test source_file)
177  if(NOT EXISTS ${source_file})
178    return()
179  endif()
180
181  file(READ "${source_file}" source_file_content)
182  string(REGEX
183    MATCHALL "(BOOST_FIXTURE_TEST_SUITE|BOOST_AUTO_TEST_SUITE)\\(([A-Za-z0-9_]+)"
184    test_suite_macro "${source_file_content}"
185  )
186  list(TRANSFORM test_suite_macro
187    REPLACE "(BOOST_FIXTURE_TEST_SUITE|BOOST_AUTO_TEST_SUITE)\\(" ""
188  )
189  foreach(test_suite_name IN LISTS test_suite_macro)
190    add_test(NAME ${test_suite_name}
191      COMMAND test_bitcoin --run_test=${test_suite_name} --catch_system_error=no --log_level=test_suite -- -printtoconsole=1
192    )
193    set_property(TEST ${test_suite_name} PROPERTY
194      SKIP_REGULAR_EXPRESSION
195        "no test cases matching filter"
196        "skipping script_assets_test"
197    )
198  endforeach()
199endfunction()
200
201function(add_all_test_targets)
202  get_target_property(test_source_dir test_bitcoin SOURCE_DIR)
203  get_target_property(test_sources test_bitcoin SOURCES)
204  foreach(test_source ${test_sources})
205    cmake_path(IS_RELATIVE test_source result)
206    if(result)
207      cmake_path(APPEND test_source_dir ${test_source} OUTPUT_VARIABLE test_source)
208    endif()
209    add_boost_test(${test_source})
210  endforeach()
211endfunction()
212
213if(ENABLE_WALLET)
214  add_subdirectory(${PROJECT_SOURCE_DIR}/src/wallet/test wallet)
215endif()
216
217if(ENABLE_IPC)
218  add_subdirectory(${PROJECT_SOURCE_DIR}/src/ipc/test ipc)
219endif()
220
221add_all_test_targets()
222
223install_binary_component(test_bitcoin INTERNAL)
224